llGetAgentInfo

integer llGetAgentInfo(key id) 

Returns a bitfield of id agent information:

Notes on the above:

• Agents are IN_AIR and not FLYING when they are jumping, falling or kept away from the ground by means of a script.
• Agents can have ATTACHMENTS that are not SCRIPTED
• Agents can be SITTING on the ground, which means they are not sitting ON_OBJECT. (When sitting on an object, they are both SITTING and ON_OBJECT.)
• The agent defined by id must be in the same simulator as the script calling this function.

Example:

// when touched, check if the agent is flying and say so.
default
{
    touch_start(integer total_number)
    {
        // we use a FOR loop here because two people can click the object at the same time.
        integer i;
        for (i = 0; i < total_number; i++)
        {
            // llGetAgentInfo returns a bitfield. Use & instead of == for comparisons.
            if (llGetAgentInfo(llDetectedKey(i)) & AGENT_FLYING) 
            {
                llSay(0, llDetectedName(i) + ", you're flying.");
            }
            
            else
            {
                llSay(0, llDetectedName(i) + ", you're not flying.");
            }
        }
    }
}

Also compare with llRequestAgentData.

Q: I can’t find ‘Always Run’ in the client, and it seems to be off. Is this deprecated?
A: It’s in the World menu. It also has a hotkey, ctrl + r.

Q: Is there a way to find out additional information about attachments found with AGENT_ATTACHMENTS or AGENT_SCRIPTED?
A: No. There’s no way to determine how many attachments an avatar has, nor where they’re attached, or what they are.