changed

changed(integer change)

The changed event is invoked when operations change certain properties of the prim/object. The change parameter is a bit field of one or more of the following values:

Notes:

• The change parameter describes only what type of change happened, not the difference between the original and changed versions of the object. If you need to determine exactly what changed, the script must store the relevant properties and compare the values from before and after the change.
• Prim/object position and rotation are not currently detected when changed but can be via a timer and llGetRot and llGetPos. Position changes can also be detected by using the moving_start and moving_end events.
• When an avatar sits on an object, they seem to become part of the linkset.
• A changed() event is raised with CHANGED_LINK as the parameter when an avatar sits on an object or un-sits. To find out what happened, use llAvatarOnSitTarget which returns the NULL_KEY if no avatar is sitting on the object, or the key of the avatar that is sitting at the sit target.

Example:

// When an avatar sits on the object containing this script,
// the object will say "Get off!" and then force the avatar to stand up.
default {
    state_entry() {
        llSitTarget(<0, 0, 0.1>, ZERO_ROTATION); // needed for llAvatarOnSitTarget to work
    }
    
    changed(integer change) { // something changed
        if (change & CHANGED_LINK) { // and it was a link change
           // llSleep(0.5); // llUnSit works better with this delay
            key av = llAvatarOnSitTarget();
            if (av) { // somebody is sitting on me
                llSay(0, "Get off!"); // say in chat when person is remove from prim
                llUnSit(av); // unsit him
            }
        }
    }
}

Details

Aside from the above, the changed() event is also not triggered:

• when an object changes position. (Use moving_start() and moving_end().)
• when an object changes rotation.
• when changing the object’s name or description.
• when changing the object’s group. (not deeding the object to a group — that’ll trigger CHANGED_OWNER)
• when toggling “Share with group”, “Allow anyone to move”, “Allow anyone to copy”, setting the object “For Sale”, changing any of the sale settings, or setting “Next owner can:”.
• when toggling “Lock”, “Physics”, “Temporary” or “Phantom”.
• when setting prim’s material.
• when setting prim’s light properties.
• when using llSetText.
• when using llParticleSystem.
• in a worn attachment when the owner attaches or detaches it. (Use attach().)
• in a worn attachment when the wearer sits on something.
• when the object is selected/edited.

This script uses the changed event with a few other functions to see which notecard was updated, added, or deleted

//written by Ruthven Willenov, added to lslwiki 9/23/2009
list notes;
list ids;
integer note = INVENTORY_NOTECARD;

default
{
    state_entry()
    {
        integer tot = llGetInventoryNumber(note);
        integer i = 0;
        for(i;i < tot;++i)
            {
                string name = llGetInventoryName(note,i);
                key id = llGetInventoryKey(name);
                integer index = llListFindList((list)name,notes);
                if(index = -1 )
                {
                    notes += name;
                    ids += id;
                    llOwnerSay("Added notecard named: " + name);
                }
            }
        }
    changed(integer change)
    {
        if(change & CHANGED_INVENTORY)
        {
            integer tot = llGetInventoryNumber(note);
            integer i = 0;
            for(i;i < tot;++i)
            {
                string name = llGetInventoryName(note,i);
                key id = llGetInventoryKey(name);
                integer index = llListFindList(notes,(list)name);
                if(index == -1 )
                {
                    notes += name;
                    ids += id;
                    llOwnerSay("Added notecard named: " + name);
                }
                else
                if(index >= 0)
                {
                    if(llList2Key(ids,index) != id)
                    {
                        ids = llDeleteSubList(ids,index,index);
                        ids = llListInsertList(ids,(list)id,index);
                        llOwnerSay(name + " was updated");
                    }
                }
            }
            integer len = llGetListLength(notes)-1;
            for(len; len >= 0; --len)
            {
                string name = llList2String(notes,len);
                integer type = llGetInventoryType(name);
                if(type == -1)
                {
                    llOwnerSay(name + " was removed.");
                    notes = llDeleteSubList(notes,len,len);
                    ids = llDeleteSubList(ids,len,len);
                }
            }                
        }
    }
                        
}

Q and A: